chundoong-lab-ta/SamsungDS22/submissions/HW6/minseok_5.oh/mat_mul.cu

#include "mat_mul.h"

#include <cstdio>
#include <cuda_runtime.h>

#define CUDA_CALL(f)                                                           \
  {                                                                            \
    cudaError_t err = (f);                                                     \
    if (err != cudaSuccess) {                                                  \
      fprintf(stderr, "CUDA error at [%s:%d] %d %s\n", __FILE__, __LINE__,     \
              err, cudaGetErrorString(err));                                   \
      exit(1);                                                                 \
    }                                                                          \
  }

#define MAX_NUM_GPU 4
int num_devices = 0;

#define TS  32
#define WPT 8
#define RTS 4

__global__ void sgemm(float *A, float *B, float *C, int M, int N, int K) {

    int row = threadIdx.x;
    int col = threadIdx.y;

    int global_row = blockDim.x * WPT * blockIdx.x + threadIdx.x;
    int global_col = blockDim.y       * blockIdx.y + threadIdx.y;

    __shared__ float Asub[TS][TS];
    __shared__ float Bsub[TS][TS];

    float acc[WPT];

    for (int w = 0; w < WPT; w++) {
        acc[w] = 0.0f;
    }

    int num_tiles = (K + TS -1) / TS;

    for (int t = 0; t < num_tiles; t++) {
      for (int w = 0; w < WPT; w++) {
        int t_row = TS*t + row;
        int t_col = TS*t + col;

             if ((global_row + w*RTS) >= M)  { Asub[row + w*RTS][col] = 0.0f; }
        else if ( t_col               >= K)  { Asub[row + w*RTS][col] = 0.0f; }
        else                                 { Asub[row + w*RTS][col] = A[(global_row + w*RTS)*K + t_col]; }

             if ( global_col          >= N)  { Bsub[row + w*RTS][col] = 0.0f; }
        else if ((t_row + w*RTS)      >= K)  { Bsub[row + w*RTS][col] = 0.0f; }
        else                                 { Bsub[row + w*RTS][col] = B[(t_row + w*RTS)*N + global_col]; }
      }

      __syncthreads();

        for (int k = 0; k < TS; k++) {
          for (int w = 0; w < WPT; w++) {
            acc[w] += Asub[row + w*RTS][k] * Bsub[k][col];
          }
        }

      __syncthreads();
    }

    for (int w = 0; w < WPT; w++) {

        if ( global_col          >= N) continue;
        if ((global_row + w*RTS) >= M) continue;

        C[(global_row + w*RTS)*N + global_col] = acc[w];
    }
}

// Array of device (GPU) pointers
static float *a_d[MAX_NUM_GPU];
static float *b_d[MAX_NUM_GPU];
static float *c_d[MAX_NUM_GPU];
static int M, N, K;
static int Mbegin[MAX_NUM_GPU], Mend[MAX_NUM_GPU];

void mat_mul(float *_A, float *_B, float *_C, int _M, int _N, int _K) {

  // Launch kernel on every GPU
  for (int i = 0; i < num_devices; i++) {

    int M_size = Mend[i] - Mbegin[i];

    dim3 blockDim(TS/WPT, TS, 1);                           
    dim3 gridDim (((M_size+TS-1)/TS), (N+TS-1)/TS, 1);

    CUDA_CALL( cudaSetDevice(i) );
    sgemm<<<gridDim, blockDim>>>(a_d[i], b_d[i], c_d[i], M_size, N, K);

  }

  // DO NOT REMOVE; NEEDED FOR TIME MEASURE
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaDeviceSynchronize() );
  }
}

void mat_mul_init(float *A, float *B, float *C, int _M, int _N, int _K) {
  M = _M, N = _N, K = _K;

  CUDA_CALL( cudaGetDeviceCount(&num_devices) );

  printf("Using %d devices\n", num_devices);
  for (int i = 0; i < num_devices; i++) {
    cudaDeviceProp prop;
    CUDA_CALL( cudaGetDeviceProperties(&prop, i) );

    // Try printing more detailed information here
    printf("[GPU %d] %s\n", i, prop.name);
  }

  if (num_devices <= 0) {
    printf("No CUDA device found. Aborting\n");
    exit(1);
  }

  // Setup problem size for each GPU
  for (int i = 0; i < num_devices; i++) {
    Mbegin[i] = (M / num_devices) * i;
    Mend[i] = (M / num_devices) * (i + 1);
  }
  Mend[num_devices - 1] = M;

  // Allocate device memory for each GPU
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaSetDevice(i) );
    CUDA_CALL( cudaMalloc(&a_d[i], (Mend[i] - Mbegin[i]) * K * sizeof(float)) );
    CUDA_CALL( cudaMalloc(&b_d[i], K * N * sizeof(float)) );
    CUDA_CALL( cudaMalloc(&c_d[i], (Mend[i] - Mbegin[i]) * N * sizeof(float)) );
  }

  // Upload A and B matrix to every GPU
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaMemcpy(a_d[i], A + Mbegin[i] * K,
               (Mend[i] - Mbegin[i]) * K * sizeof(float),
               cudaMemcpyHostToDevice) );
    CUDA_CALL( cudaMemcpy(b_d[i], B, K * N * sizeof(float), cudaMemcpyHostToDevice) );
  }

  // DO NOT REMOVE; NEEDED FOR TIME MEASURE
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaDeviceSynchronize() );
  }
}

void mat_mul_final(float *A, float *B, float *C, int M, int N, int K) {
  // Do any post-matmul cleanup work here.

  // Download C matrix from GPUs
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaMemcpy(C + Mbegin[i] * N, c_d[i],
               (Mend[i] - Mbegin[i]) * N * sizeof(float),
               cudaMemcpyDeviceToHost) );
  }

  // DO NOT REMOVE; NEEDED FOR TIME MEASURE
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaDeviceSynchronize() );
  }
}