#define TS 32
#define WPT 8

__kernel void sgemm(__global float *A, __global float *B, __global float *C, int M, int N, int K) {
// Thread identifiers
  const int row = get_local_id(0);
  const int col = get_local_id(1);
  const int global_row = TS * get_group_id(0) + row;
  const int global_col = TS * get_group_id(1) + col;
  int RTS = TS/WPT;
 
  __local float Asub[TS][TS];
  __local float Bsub[TS][TS];

  float acc[WPT];
  for(int w=0; w<WPT; w++){
      acc[w] = 0.0f;	  
  }
  

  int num_tiles = K < TS ? 1 : K/TS;
  int check = K%TS;
  if(check != 0)
      num_tiles = (K+TS-1)/TS;// + 1; //K/TS + 1;

  for(int t = 0; t < num_tiles; t++){

      for(int w=0; w < WPT; w++){
          const int t_row = TS * t + row;
          const int t_col = TS * t + col;
              
          if((global_row + w*RTS) < M && t_col < K)
	      Asub[row + w*RTS][col] = A[(global_row + w*RTS) * K + t_col];
	  else    
	      Asub[row + w*RTS][col] = 0;
        
          
	  if(global_col < N && (t_row + w*RTS) < K)
	     Bsub[row + w*RTS][col] = B[(t_row + w*RTS) * N + global_col];
	  else
	     Bsub[row + w*RTS][col] = 0;
      }
      barrier(CLK_LOCAL_MEM_FENCE);

      for(int k=0; k < TS; k++){
          for(int w=0; w < WPT; w++){
              acc[w] += Asub[row + w*RTS][k] * Bsub[k][col];
	  }
      }
      barrier(CLK_LOCAL_MEM_FENCE);
  }

  for(int w=0; w<WPT; w++){
      if((global_row + w*RTS) < M && global_col < N)	  
         C[(global_row + w*RTS)*N + global_col] = acc[w];
  }

}