#define TS   32
#define WPT  8 
#define RTS  TS/WPT

__kernel void sgemm(__global float *A, __global float *B, __global float *C, int M, int N, int K) {
    // Thread identifiers
    const int row = get_local_id(0);   // row index of C
    const int col = get_local_id(1);   // column index of C
    const int global_row = TS * get_group_id(0) + row;   // row ID of C [0:M)
    const int global_col = TS * get_group_id(1) + col;   // col ID of C [0:N/8)
  
    __local float Asub[TS][TS];
    __local float Bsub[TS][TS];
  
    float acc[WPT];
    for (int w = 0; w < WPT; w++) {
        acc[w] = 0.0f;
    }
    
    const int num_tiles = (K + TS -1) / TS;

    for (int t = 0; t < num_tiles; t++) {
      for (int w = 0; w < WPT; w++) {
        const int t_row = TS*t + row;
        const int t_col = TS*t + col;

	  
             if ((global_row + w*RTS) >= M)  { Asub[row + w*RTS][col] = 0.0f; } 
        else if ( t_col               >= K)  { Asub[row + w*RTS][col] = 0.0f; } 
        else                                 { Asub[row + w*RTS][col] = A[(global_row + w*RTS)*K + t_col]; }
                                          
             if ( global_col          >= N)  { Bsub[row + w*RTS][col] = 0.0f; } 
        else if ((t_row + w*RTS)      >= K)  { Bsub[row + w*RTS][col] = 0.0f; } 
        else                                 { Bsub[row + w*RTS][col] = B[(t_row + w*RTS)*N + global_col]; }
      }

      barrier(CLK_LOCAL_MEM_FENCE);
  
      for (int k = 0; k < TS; k++) {
        for (int w = 0; w < WPT; w++) {
          acc[w] += Asub[row + w*RTS][k] * Bsub[k][col];
        }
      }

      barrier(CLK_LOCAL_MEM_FENCE);
    }
  
    for (int w = 0; w < WPT; w++) {

	if ( global_col          >= N) continue;
        if ((global_row + w*RTS) >= M) continue;

        C[(global_row + w*RTS)*N + global_col] = acc[w];
    }
}