chundoong-lab-ta/SamsungDS22/submissions/HW6/gyeongmin.ha/mat_mul.cu

#include "mat_mul.h"

#include <cstdio>
#include <cuda_runtime.h>

#define CUDA_CALL(f)                                                           \
  {                                                                            \
    cudaError_t err = (f);                                                     \
    if (err != cudaSuccess) {                                                  \
      fprintf(stderr, "CUDA error at [%s:%d] %d %s\n", __FILE__, __LINE__,     \
              err, cudaGetErrorString(err));                                   \
      exit(1);                                                                 \
    }                                                                          \
  }

#define TS 32
#define WPT 16
#define RTS (TS/WPT)
#define MAX_NUM_GPU 4
int num_devices = 4;

__global__ void sgemm(float *A, float *B, float *C, int M, int N, int K) {

    // Thread identifiers
    const int row = threadIdx.x; // Local row ID (max: TS)
    const int col = threadIdx.y; // Local col ID (max: TS)
    const int globalRow = (blockDim.x*WPT)*blockIdx.x + threadIdx.x; // Row ID of C (0..M)
    const int globalCol =  blockDim.y*blockIdx.y + threadIdx.y; // Col ID of C (0..N)
 
    // Local memory to fit a tile of TS*TS elements of A and B
    __shared__ float Asub[TS][TS];
    __shared__ float Bsub[TS][TS];
 
    // Initialise the accumulation register
    float acc[WPT];
    for (int w=0; w<WPT; w++) {
        acc[w] = 0.0f;
    }
    
    // Loop over all tiles
    //const int numTiles = K/TS;
    const int numTiles = (K+TS-1)/TS;
    for (int t=0; t<numTiles; t++) {
 
        // Load one tile of A and B into local memory
        for (int w=0; w<WPT; w++) {
            const int tiledRow = TS*t + row;
            const int tiledCol = TS*t + col;

	    if(globalRow + w*RTS >= M || tiledCol >= K)
	    {
	        Asub[row + w*RTS][col] = 0.0f;
            }
            else
            {
		Asub[row + w*RTS][col] = A[(globalRow + w*RTS)*K + tiledCol];
            }
	    if(globalCol >= N  || tiledRow + w*RTS >= K)
	    {
		Bsub[row + w*RTS][col] = 0.0f;
	    }
	    else
	    {
		Bsub[row + w*RTS][col] = B[(tiledRow + w*RTS)*N + globalCol];
	    }
        }
        
        // Synchronise to make sure the tile is loaded
        __syncthreads();
 
        // Perform the computation for a single tile
        for (int k=0; k<TS; k++) {
            for (int w=0; w<WPT; w++) {
                //acc[w] += Asub[k][row] * Bsub[col + w*RTS][k];
                acc[w] += Asub[row+w*RTS][k] * Bsub[k][col];
            }
        }
 
        // Synchronise before loading the next tile
        __syncthreads();
    }
 
    // Store the final result in C
    for (int w=0; w<WPT; w++) {
        //C[(globalCol + w*RTS)*M + globalRow] = acc[w];
        //C[(globalRow + w*RTS)*N + globalCol] = acc[w];
	if(globalRow + w*RTS >= M || globalCol >= N)
	{
	    continue;
	}
	else
	{
	    C[(globalRow + w*RTS)*N + globalCol] = acc[w];
	}
    }
}



// Array of device (GPU) pointers
static float *a_d[MAX_NUM_GPU];
static float *b_d[MAX_NUM_GPU];
static float *c_d[MAX_NUM_GPU];
static int M, N, K;
static int Mbegin[MAX_NUM_GPU], Mend[MAX_NUM_GPU];
static int size[MAX_NUM_GPU];

void mat_mul(float *_A, float *_B, float *_C, int _M, int _N, int _K) {

  // Launch kernel on every GPU
  for (int i = 0; i < num_devices; i++) {
    dim3 blockDim(TS/WPT, TS, 1);
    dim3 gridDim(((Mend[i] - Mbegin[i]+TS-1)/TS), (N+TS-1)/TS, 1);

    CUDA_CALL( cudaSetDevice(i) );
    sgemm<<<gridDim, blockDim>>>(a_d[i], b_d[i], c_d[i], size[i], N, K);
  }

  // DO NOT REMOVE; NEEDED FOR TIME MEASURE
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaDeviceSynchronize() );
    CUDA_CALL( cudaSetDevice(i) );
  }
}

void mat_mul_init(float *A, float *B, float *C, int _M, int _N, int _K) {
  M = _M, N = _N, K = _K;

  CUDA_CALL( cudaGetDeviceCount(&num_devices) );

  printf("Using %d devices\n", num_devices);
  for (int i = 0; i < num_devices; i++) {
    cudaDeviceProp prop;
    CUDA_CALL( cudaGetDeviceProperties(&prop, i) );

    // Try printing more detailed information here
    printf("[GPU %d] %s\n", i, prop.name);
  }

  if (num_devices <= 0) {
    printf("No CUDA device found. Aborting\n");
    exit(1);
  }

  
  for (int i = 0; i < num_devices; i++) {
    Mbegin[i] = (M / num_devices) * i;
    Mend[i] = (M / num_devices) * (i + 1);
  }
  Mend[num_devices - 1] = M; 
  
  for (int i = 0; i < num_devices; i++) {
    size[i] = Mend[i] - Mbegin[i];
  }


  // Allocate device memory for each GPU
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaSetDevice(i) );
    CUDA_CALL( cudaMalloc(&a_d[i], (Mend[i] - Mbegin[i]) * K * sizeof(float)) );
    CUDA_CALL( cudaMalloc(&b_d[i], K * N * sizeof(float)) );
    CUDA_CALL( cudaMalloc(&c_d[i], (Mend[i] - Mbegin[i]) * N * sizeof(float)) );
  }

  // Upload A and B matrix to every GPU
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaMemcpy(a_d[i], A + Mbegin[i] * K,
               (Mend[i] - Mbegin[i]) * K * sizeof(float),
               cudaMemcpyHostToDevice) );
    CUDA_CALL( cudaMemcpy(b_d[i], B, K * N * sizeof(float), cudaMemcpyHostToDevice) );
  }

  // DO NOT REMOVE; NEEDED FOR TIME MEASURE
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaDeviceSynchronize() );
  }
}

void mat_mul_final(float *A, float *B, float *C, int M, int N, int K) {
  // Do any post-matmul cleanup work here.

  // Download C matrix from GPUs
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaMemcpy(C + Mbegin[i] * N, c_d[i],
               (Mend[i] - Mbegin[i]) * N * sizeof(float),
               cudaMemcpyDeviceToHost) );
  }

  // DO NOT REMOVE; NEEDED FOR TIME MEASURE
  for (int i = 0; i < num_devices; i++) {
    CUDA_CALL( cudaDeviceSynchronize() );
  }
}